home *** CD-ROM | disk | FTP | other *** search
/ Shareware Extravaganza - Disc 4 / Shareware Extravaganza - Over 25,000 Programs (The Ultimate Shareware Company)(Disc 4 of 4)(1993).iso / cad / pspice3.zip / OPNOM.LIB < prev    next >
Text File  |  1986-09-04  |  2KB  |  58 lines
  1. * Library of Op Amp subcircuit definitions
  2. *
  3. * This is a reduced version of MicroSim's opamp subcircuit library.
  4. *   You are welcome to make as many copies of it as you find convenient.
  5. *
  6. * Release date: 86/01/04
  7. *
  8. * The parameters in this opamp library were derived from the data
  9. * sheets for each part.  The macromodel used is described in:
  10. *
  11. *    Macromodeling of Integrated Circuit Operational Amplifiers
  12. *        by Graeme Boyle, Barry Cohn, Donald Pederson, and
  13. *           James Solomon
  14. *    IEEE Journal of Solid-State Circuits, Vol. SC-9, no. 6,    Dec. 1974
  15. *
  16. * The opamps are modelled at room temperature.  The macro model
  17. * does not track changes with temperature.  This library file contains
  18. * models for nominal, not worst case, devices.
  19. *
  20. * Note: Each macromodel consists of a subcircuit definition AND a set
  21. *    of .MODEL statements.  The .MODEL statements should be put into
  22. *    the main circuit file along with the subcircuit definition.
  23. *
  24. *
  25. .SUBCKT UA741    1   2   3   4   5   6
  26. *               Vi+ Vi- gnd Vp+ Vp- Vout
  27. Q1 11 1 13 UA741QA
  28. Q2 12 2 14 UA741QB
  29. RC1 4 11 5.305165D+03
  30. RC2 4 12 5.305165D+03
  31. C1 11 12 5.459553D-12
  32. RE1 13 10 2.151297D+03
  33. RE2 14 10 2.151297D+03
  34. IEE 10 5 1.666000D-05
  35. CE 10 3 3.000000D-12
  36. RE 10 3 1.200480D+07
  37. GCM 3 21 10 3 5.960753D-09
  38. GA 21 3 12 11 1.884955D-04
  39. R2 21 3 1.000000D+05
  40. C2 21 22 3.000000D-11
  41. GB 22 3 21 3 2.357851D+02
  42. RO2 22 3 4.500000D+01
  43. D1 22 31 UA741DA
  44. D2 31 22 UA741DA
  45. EC 31 3 6 3 1.0
  46. RO1 22 6 3.000000D+01
  47. D3 6 24 UA741DB
  48. VC 4 24 2.803238D+00
  49. D4 25 6 UA741DB
  50. VE 25 5 2.803238D+00
  51. .ENDS
  52. .MODEL UA741DA D (IS=9.762287D-11)
  53. .MODEL UA741DB D (IS=8.000000D-16)
  54. .MODEL UA741QA NPN (IS=8.000000D-16 BF=9.166667D+01)
  55. .MODEL UA741QB NPN (IS=8.309478D-16 BF=1.178571D+02)
  56. *
  57. * End of library file
  58.